1 files changed, 31 insertions, 0 deletions

diff --git a/buildSrc/src/main/kotlin/tools/refinery/gradle/java-test-fixtures.gradle.kts b/buildSrc/src/main/kotlin/tools/refinery/gradle/java-test-fixtures.gradle.kts
new file mode 100644
index 00000000..7e599c3f
--- /dev/null
+++ b/buildSrc/src/main/kotlin/tools/refinery/gradle/java-test-fixtures.gradle.kts
@@ -0,0 +1,31 @@
+package tools.refinery.gradle
+
+import org.gradle.plugins.ide.eclipse.model.AbstractClasspathEntry
+import tools.refinery.gradle.utils.EclipseUtils
+
+plugins {
+        `java-test-fixtures`
+        id("tools.refinery.gradle.internal.java-conventions")
+}
+
+eclipse.classpath {
+        containsTestFixtures.set(true)
+
+        EclipseUtils.whenClasspathFileMerged(file) { eclipseClasspath ->
+                val hasTest = eclipseClasspath.entries.any { entry ->
+                        entry is AbstractClasspathEntry && entry.entryAttributes["gradle_scope"] == "test"
+                }
+                EclipseUtils.patchClasspathEntries(eclipseClasspath) { entry ->
+                        // Workaround https://github.com/gradle/gradle/issues/11845 based on
+                        // https://discuss.gradle.org/t/gradle-used-by-scope-not-correctly-generated-when-the-java-test-fixtures-plugin-is-used/39935/2
+                        EclipseUtils.patchGradleUsedByScope(entry) { usedBy ->
+                                if (usedBy.contains("main")) {
+                                        usedBy += "testFixtures"
+                                }
+                                if (hasTest && usedBy.contains("testFixtures")) {
+                                        usedBy += "test"
+                                }
+                        }
+                }
+        }
+}