1 files changed, 45 insertions, 0 deletions

diff --git a/buildSrc/src/main/groovy/tools.refinery.java-conventions.gradle b/buildSrc/src/main/groovy/tools.refinery.java-conventions.gradle
new file mode 100644
index 00000000..6bea6e46
--- /dev/null
+++ b/buildSrc/src/main/groovy/tools.refinery.java-conventions.gradle
@@ -0,0 +1,45 @@
+plugins {
+        id 'eclipse'
+}
+
+repositories {
+        mavenCentral()
+        maven {
+                url 'https://repo.eclipse.org/content/groups/releases/'
+        }
+}
+
+sourceCompatibility = '17'
+targetCompatibility = '17'
+
+tasks.named('jar') {
+        manifest {
+                attributes 'Bundle-SymbolicName': project.name
+        }
+}
+
+def generateEclipseSourceFolders = tasks.register('generateEclipseSourceFolders')
+
+tasks.register('prepareEclipse') {
+        dependsOn generateEclipseSourceFolders
+        dependsOn tasks.named('eclipseJdt')
+}
+
+tasks.named('eclipseClasspath') {
+        dependsOn generateEclipseSourceFolders
+}
+
+eclipse {
+        classpath.file.whenMerged {
+                for (entry in entries) {
+                        if (entry.path.endsWith('-gen')) {
+                                entry.entryAttributes['ignore_optional_problems'] = true
+                        }
+                }
+        }
+
+        jdt.file.withProperties { properties ->
+                // Allow @SupperessWarnings to suppress SonarLint warnings
+                properties['org.eclipse.jdt.core.compiler.problem.unhandledWarningToken'] = 'ignore'
+        }
+}