build: improve Xtext project isolation

* Avoid writing generated source files directly into sibling projects.
* Full project isolation cannot be enabled yet, because the frontend plugin
  still requires cross-projects task dependencies for Node.js installation.

1 files changed, 23 insertions, 2 deletions

diff --git a/buildSrc/src/main/kotlin/tools/refinery/gradle/xtext-generated.gradle.kts b/buildSrc/src/main/kotlin/tools/refinery/gradle/xtext-generated.gradle.kts
index 59fe921b..6cb1d7b5 100644
--- a/buildSrc/src/main/kotlin/tools/refinery/gradle/xtext-generated.gradle.kts
+++ b/buildSrc/src/main/kotlin/tools/refinery/gradle/xtext-generated.gradle.kts
@@ -14,15 +14,36 @@ plugins {
 
 val xtextGenPath = "src/main/xtext-gen"
 
+val xtextGenerated: Configuration by configurations.creating {
+        isCanBeConsumed = false
+        isCanBeResolved = true
+}
+
 sourceSets.main {
         java.srcDir(xtextGenPath)
         resources.srcDir(xtextGenPath)
 }
 
-tasks.clean {
-        delete(xtextGenPath)
+tasks {
+        // Based on the idea from https://stackoverflow.com/a/57788355 to safely consume generated sources in sibling
+        // projects.
+        val syncXtextGeneratedSources by tasks.creating(Sync::class) {
+                from(xtextGenerated)
+                into(xtextGenPath)
+        }
+
+        for (taskName in listOf("compileJava", "processResources", "generateEclipseSourceFolders")) {
+                tasks.named(taskName) {
+                        dependsOn(syncXtextGeneratedSources)
+                }
+        }
+
+        clean {
+                delete(xtextGenPath)
+        }
 }
 
+
 sonarqube.properties {
         SonarPropertiesUtils.addToList(properties, "sonar.exclusions", "$xtextGenPath/**")
 }