1 files changed, 71 insertions, 118 deletions

diff --git a/meson.build b/meson.build
index 38a55678..f8bf4f80 100644
--- a/meson.build
+++ b/meson.build
@@ -1,9 +1,9 @@
 project(
         'sway',
         'c',
-        version: '1.5', #release_version
+        version: '1.10-dev',
         license: 'MIT',
-        meson_version: '>=0.53.0',
+        meson_version: '>=0.60.0',
         default_options: [
                 'c_std=c11',
                 'warning_level=2',
@@ -18,6 +18,7 @@ add_project_arguments(
                 '-Wno-unused-parameter',
                 '-Wno-unused-result',
                 '-Wno-missing-braces',
+                '-Wno-format-zero-length',
                 '-Wundef',
                 '-Wvla',
         ],
@@ -35,79 +36,65 @@ if is_freebsd
         add_project_arguments('-D_C11_SOURCE', language: 'c')
 endif
 
-jsonc          = dependency('json-c', version: '>=0.13')
-pcre           = dependency('libpcre')
-wayland_server = dependency('wayland-server')
-wayland_client = dependency('wayland-client')
-wayland_cursor = dependency('wayland-cursor')
-wayland_egl    = dependency('wayland-egl')
-wayland_protos = dependency('wayland-protocols', version: '>=1.14')
-xkbcommon      = dependency('xkbcommon')
-cairo          = dependency('cairo')
-pango          = dependency('pango')
-pangocairo     = dependency('pangocairo')
-gdk_pixbuf     = dependency('gdk-pixbuf-2.0', required: get_option('gdk-pixbuf'))
-pixman         = dependency('pixman-1')
-glesv2         = dependency('glesv2')
-libevdev       = dependency('libevdev')
-libinput       = dependency('libinput', version: '>=1.6.0')
-xcb            = dependency('xcb', required: get_option('xwayland'))
-bash_comp      = dependency('bash-completion', required: false)
-fish_comp      = dependency('fish', required: false)
-math           = cc.find_library('m')
-rt             = cc.find_library('rt')
-
-# Try first to find wlroots as a subproject, then as a system dependency
-wlroots_version = ['>=0.12.0', '<0.13.0']
-wlroots_proj = subproject(
+# Execute the wlroots subproject, if any
+wlroots_version = ['>=0.18.0', '<0.19.0']
+subproject(
         'wlroots',
         default_options: ['examples=false'],
         required: false,
         version: wlroots_version,
 )
+wlroots = dependency('wlroots', version: wlroots_version)
 wlroots_features = {
         'xwayland': false,
-        'systemd': false,
-        'elogind': false,
-        'libseat': false,
+        'libinput_backend': false,
+        'session': false,
 }
-if wlroots_proj.found()
-        wlroots = wlroots_proj.get_variable('wlroots')
-        wlroots_conf = wlroots_proj.get_variable('conf_data')
-        foreach name, _ : wlroots_features
-                has = wlroots_conf.get('WLR_HAS_' + name.to_upper()) == 1
-                wlroots_features += { name: has }
-        endforeach
-else
-        wlroots = dependency('wlroots', version: wlroots_version)
-        foreach name, _ : wlroots_features
-                has = cc.get_define('WLR_HAS_' + name.to_upper(), prefix: '#include <wlr/config.h>', dependencies: wlroots) == '1'
-                wlroots_features += { name: has }
-        endforeach
-endif
+foreach name, _ : wlroots_features
+        var_name = 'have_' + name.underscorify()
+        have = wlroots.get_variable(pkgconfig: var_name, internal: var_name) == 'true'
+        wlroots_features += { name: have }
+endforeach
 
 if get_option('xwayland').enabled() and not wlroots_features['xwayland']
         error('Cannot enable Xwayland in sway: wlroots has been built without Xwayland support')
 endif
-have_xwayland = xcb.found() and wlroots_features['xwayland']
+
+null_dep = dependency('', required: false)
+
+jsonc = dependency('json-c', version: '>=0.13')
+pcre2 = dependency('libpcre2-8')
+wayland_server = dependency('wayland-server', version: '>=1.21.0')
+wayland_client = dependency('wayland-client')
+wayland_cursor = dependency('wayland-cursor')
+wayland_protos = dependency('wayland-protocols', version: '>=1.24')
+xkbcommon = dependency('xkbcommon', version: '>=1.5.0')
+cairo = dependency('cairo')
+pango = dependency('pango')
+pangocairo = dependency('pangocairo')
+gdk_pixbuf = dependency('gdk-pixbuf-2.0', required: get_option('gdk-pixbuf'))
+pixman = dependency('pixman-1')
+libevdev = dependency('libevdev')
+libinput = wlroots_features['libinput_backend'] ? dependency('libinput', version: '>=1.21.0') : null_dep
+xcb = dependency('xcb', required: get_option('xwayland'))
+drm = dependency('libdrm')
+libudev = wlroots_features['libinput_backend'] ? dependency('libudev') : null_dep
+math = cc.find_library('m')
+rt = cc.find_library('rt')
+xcb_icccm = dependency('xcb-icccm', required: get_option('xwayland'))
+threads = dependency('threads') # for pthread_setschedparam
+
+have_xwayland = xcb.found() and xcb_icccm.found() and wlroots_features['xwayland']
 
 if get_option('sd-bus-provider') == 'auto'
         if not get_option('tray').disabled()
                 assert(get_option('auto_features').auto(), 'sd-bus-provider must not be set to auto since auto_features != auto')
         endif
-        sdbus = dependency('libsystemd',
+        sdbus = dependency(['libsystemd', 'libelogind'],
                 required: false,
                 version: '>=239',
-                not_found_message: 'libsystemd not found, trying libelogind',
         )
         if not sdbus.found()
-                sdbus = dependency('libelogind',
-                        required: false,
-                        version: '>=239',
-                        not_found_message: 'libelogind not found, trying basu',
-                )
-        endif
-        if not sdbus.found()
                 sdbus = dependency('basu', required: false)
         endif
 else
@@ -128,11 +115,15 @@ conf_data.set10('HAVE_LIBSYSTEMD', sdbus.found() and sdbus.name() == 'libsystemd
 conf_data.set10('HAVE_LIBELOGIND', sdbus.found() and sdbus.name() == 'libelogind')
 conf_data.set10('HAVE_BASU', sdbus.found() and sdbus.name() == 'basu')
 conf_data.set10('HAVE_TRAY', have_tray)
+conf_data.set10('HAVE_LIBINPUT_CONFIG_ACCEL_PROFILE_CUSTOM', cc.has_header_symbol(
+        'libinput.h',
+        'LIBINPUT_CONFIG_ACCEL_PROFILE_CUSTOM',
+        dependencies: libinput,
+))
 
 scdoc = dependency('scdoc', version: '>=1.9.2', native: true, required: get_option('man-pages'))
 if scdoc.found()
-        scdoc_prog = find_program(scdoc.get_pkgconfig_variable('scdoc'), native: true)
-        sh = find_program('sh', native: true)
+        scdoc_prog = find_program(scdoc.get_variable(pkgconfig: 'scdoc'), native: true)
         mandir = get_option('mandir')
         man_files = [
                 'sway/sway.1.scd',
@@ -143,9 +134,15 @@ if scdoc.found()
                 'sway/sway-output.5.scd',
                 'swaybar/swaybar-protocol.7.scd',
                 'swaymsg/swaymsg.1.scd',
-                'swaynag/swaynag.1.scd',
-                'swaynag/swaynag.5.scd',
         ]
+
+        if get_option('swaynag')
+                man_files += [
+                        'swaynag/swaynag.1.scd',
+                        'swaynag/swaynag.5.scd',
+                ]
+        endif
+
         foreach filename : man_files
                 topic = filename.split('.')[-3].split('/')[-1]
                 section = filename.split('.')[-2]
@@ -155,10 +152,10 @@ if scdoc.found()
                         output,
                         input: filename,
                         output: output,
-                        command: [
-                                sh, '-c', '@0@ < @INPUT@ > @1@'.format(scdoc_prog.path(), output)
-                        ],
+                        command: scdoc_prog,
                         install: true,
+                        feed: true,
+                        capture: true,
                         install_dir: '@0@/man@1@'.format(mandir, section)
                 )
         endforeach
@@ -169,8 +166,8 @@ add_project_arguments('-DSYSCONFDIR="/@0@"'.format(join_paths(prefix, sysconfdir
 version = '"@0@"'.format(meson.project_version())
 git = find_program('git', native: true, required: false)
 if git.found()
-        git_commit = run_command([git, 'rev-parse', '--short', 'HEAD'])
-        git_branch = run_command([git, 'rev-parse', '--abbrev-ref', 'HEAD'])
+        git_commit = run_command([git, 'rev-parse', '--short', 'HEAD'], check: false)
+        git_branch = run_command([git, 'rev-parse', '--abbrev-ref', 'HEAD'], check: false)
         if git_commit.returncode() == 0 and git_branch.returncode() == 0
                 version = '"@0@-@1@ (" __DATE__ ", branch \'@2@\')"'.format(
                         meson.project_version(),
@@ -183,7 +180,7 @@ add_project_arguments('-DSWAY_VERSION=@0@'.format(version), language: 'c')
 
 # Compute the relative path used by compiler invocations.
 source_root = meson.current_source_dir().split('/')
-build_root = meson.build_root().split('/')
+build_root = meson.global_build_root().split('/')
 relative_dir_parts = []
 i = 0
 in_prefix = true
@@ -227,9 +224,15 @@ subdir('common')
 subdir('sway')
 subdir('swaymsg')
 
-subdir('client')
-subdir('swaybar')
-subdir('swaynag')
+if get_option('swaybar') or get_option('swaynag')
+        subdir('client')
+endif
+if get_option('swaybar')
+        subdir('swaybar')
+endif
+if get_option('swaynag')
+        subdir('swaynag')
+endif
 
 config = configuration_data()
 config.set('datadir', join_paths(prefix, datadir))
@@ -264,61 +267,11 @@ if get_option('default-wallpaper')
         install_data(wallpaper_files, install_dir: wallpaper_install_dir)
 endif
 
-if get_option('zsh-completions')
-        zsh_files = files(
-                'completions/zsh/_sway',
-                'completions/zsh/_swaymsg',
-        )
-        zsh_install_dir = join_paths(datadir, 'zsh', 'site-functions')
-
-        install_data(zsh_files, install_dir: zsh_install_dir)
-endif
-
-if get_option('bash-completions')
-        bash_files = files(
-                'completions/bash/sway',
-                'completions/bash/swaybar',
-                'completions/bash/swaymsg',
-        )
-        if bash_comp.found()
-                bash_install_dir = bash_comp.get_pkgconfig_variable(
-                        'completionsdir',
-                        define_variable: ['datadir', datadir]
-                )
-        else
-                bash_install_dir = join_paths(datadir, 'bash-completion', 'completions')
-        endif
-
-        install_data(bash_files, install_dir: bash_install_dir)
-endif
-
-if get_option('fish-completions')
-        fish_files = files(
-                'completions/fish/sway.fish',
-                'completions/fish/swaymsg.fish',
-                'completions/fish/swaynag.fish',
-        )
-        if fish_comp.found()
-                fish_install_dir = fish_comp.get_pkgconfig_variable(
-                        'completionsdir',
-                        define_variable: ['datadir', datadir]
-                )
-        else
-                fish_install_dir = join_paths(datadir, 'fish', 'vendor_completions.d')
-        endif
-
-        install_data(fish_files, install_dir: fish_install_dir)
-endif
+subdir('completions')
 
 summary({
         'xwayland': have_xwayland,
         'gdk-pixbuf': gdk_pixbuf.found(),
-        'sd-bus': sdbus.found(),
         'tray': have_tray,
         'man-pages': scdoc.found(),
 }, bool_yn: true)
-
-if not wlroots_features['systemd'] and not wlroots_features['elogind'] and not wlroots_features['libseat']
-        warning('The sway binary must be setuid when compiled without (e)logind or libseat')
-        warning('You must do this manually post-install: chmod a+s /path/to/sway')
-endif