1 files changed, 36 insertions, 0 deletions

diff --git a/z3/subprojects/solver-linux-x86-64/build.gradle.kts b/z3/subprojects/solver-linux-x86-64/build.gradle.kts
new file mode 100644
index 00000000..89c737b6
--- /dev/null
+++ b/z3/subprojects/solver-linux-x86-64/build.gradle.kts
@@ -0,0 +1,36 @@
+/*
+ * SPDX-FileCopyrightText: 2023 The Refinery Authors <https://refinery.tools/>
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+plugins {
+        id("tools.refinery.z3.gradle.java-library")
+}
+
+val classifier = "z3-${version}-x64-glibc-2.31"
+val library = "z3java-linux-x86-64"
+
+dependencies {
+        z3("Z3Prover:z3:${version}:${classifier}@zip")
+}
+
+val extractZ3Libs by tasks.registering(Sync::class) {
+        dependsOn(configurations.z3)
+        from({
+                val zipFile = configurations.z3.map { it.singleFile }
+                zipTree(zipFile).matching {
+                        include("${classifier}/bin/*.so")
+                        includeEmptyDirs = false
+                }
+        })
+        eachFile {
+                val pathInBin = relativePath.segments.drop(2).toTypedArray()
+                relativePath = RelativePath(true, library, *pathInBin)
+        }
+        into(layout.buildDirectory.dir("z3-extracted"))
+}
+
+sourceSets.main {
+        resources.srcDir(extractZ3Libs)
+}