1 files changed, 38 insertions, 0 deletions

diff --git a/buildSrc/src/main/kotlin/tools/refinery/gradle/eclipse.gradle.kts b/buildSrc/src/main/kotlin/tools/refinery/gradle/eclipse.gradle.kts
new file mode 100644
index 00000000..25e7e573
--- /dev/null
+++ b/buildSrc/src/main/kotlin/tools/refinery/gradle/eclipse.gradle.kts
@@ -0,0 +1,38 @@
+package tools.refinery.gradle
+
+import java.util.Properties
+
+plugins {
+        eclipse
+}
+
+// Workaround from https://github.com/gradle/gradle/issues/898#issuecomment-885765821
+val eclipseResourceEncoding by tasks.registering {
+        val outputFile = file(".settings/org.eclipse.core.resources.prefs")
+        val encoding = providers.systemProperty("file.encoding")
+
+        inputs.property("file.encoding", encoding)
+        outputs.file(outputFile)
+
+        doLast {
+                val eclipseEncodingProperties = Properties(2)
+                eclipseEncodingProperties["eclipse.preferences.version"] = "1"
+                eclipseEncodingProperties["encoding/<project>"] = encoding.get()
+                outputFile.outputStream().use { outputStream ->
+                        eclipseEncodingProperties.store(outputStream, "generated by $name")
+                }
+        }
+}
+
+tasks.eclipse {
+        dependsOn(eclipseResourceEncoding)
+}
+
+eclipse.synchronizationTasks(eclipseResourceEncoding)
+
+tasks.register<Delete>("clobberEclipse") {
+        mustRunAfter(tasks.eclipse)
+        delete(".classpath")
+        delete(".project")
+        delete(".settings")
+}