build: convert Gradle scripts to Kotlin

Improves IDE support build scripts in IntelliJ.

There is no Eclipse IDE support, but Eclipse didn't have support for Groovy
either, so there is no degradation of functionality.

2 files changed, 65 insertions, 73 deletions

diff --git a/subprojects/language/build.gradle b/subprojects/language/build.gradle
deleted file mode 100644
index 654558e3..00000000
--- a/subprojects/language/build.gradle
+++ /dev/null
@@ -1,73 +0,0 @@
-plugins {
-        id 'refinery-java-library'
-        id 'refinery-java-test-fixtures'
-        id 'refinery-mwe2'
-        id 'refinery-sonarqube'
-        id 'refinery-xtext-conventions'
-}
-
-dependencies {
-        api platform(libs.xtext.bom)
-        api libs.ecore
-        api libs.xtext.core
-        api libs.xtext.xbase
-        api project(':refinery-language-model')
-        testFixturesApi libs.xtext.testing
-        mwe2 libs.xtext.generator
-        mwe2 libs.xtext.generator.antlr
-}
-
-sourceSets {
-        testFixtures {
-                java.srcDirs += ['src/testFixtures/xtext-gen']
-                resources.srcDirs += ['src/testFixtures/xtext-gen']
-        }
-}
-
-tasks.named('jar') {
-        from(sourceSets.main.allSource) {
-                include '**/*.xtext'
-        }
-}
-
-def generateXtextLanguage = tasks.register('generateXtextLanguage', JavaExec) {
-        mainClass = 'org.eclipse.emf.mwe2.launch.runtime.Mwe2Launcher'
-        classpath = configurations.mwe2
-        inputs.file 'src/main/java/tools/refinery/language/GenerateProblem.mwe2'
-        inputs.file 'src/main/java/tools/refinery/language/Problem.xtext'
-        outputs.dir 'src/main/xtext-gen'
-        outputs.dir 'src/testFixtures/xtext-gen'
-        outputs.dir '../language-ide/src/main/xtext-gen'
-        outputs.dir '../language-web/src/main/xtext-gen'
-        args += 'src/main/java/tools/refinery/language/GenerateProblem.mwe2'
-        args += '-p'
-        args += "rootPath=/${projectDir}/.."
-}
-
-for (taskName in [
-                'compileJava',
-                'processResources',
-                'processTestFixturesResources',
-                'generateEclipseSourceFolders'
-        ]) {
-        tasks.named(taskName) {
-                dependsOn generateXtextLanguage
-        }
-}
-
-tasks.named('clean') {
-        delete 'src/main/xtext-gen'
-        delete 'src/testFixtures/xtext-gen'
-        delete '../language-ide/src/main/xtext-gen'
-        delete '../language-web/src/main/xtext-gen'
-}
-
-sonarqube.properties {
-        properties['sonar.exclusions'] += [
-                'src/testFixtures/xtext-gen/**',
-        ]
-}
-
-eclipse.project.natures += [
-        'org.eclipse.xtext.ui.shared.xtextNature'
-]
diff --git a/subprojects/language/build.gradle.kts b/subprojects/language/build.gradle.kts
new file mode 100644
index 00000000..ed4f95a5
--- /dev/null
+++ b/subprojects/language/build.gradle.kts
@@ -0,0 +1,65 @@
+import tools.refinery.buildsrc.SonarPropertiesUtils
+
+plugins {
+        id("refinery-java-library")
+        id("refinery-java-test-fixtures")
+        id("refinery-sonarqube")
+        id("refinery-mwe2")
+        id("refinery-xtext-conventions")
+}
+
+dependencies {
+        api(platform(libs.xtext.bom))
+        api(libs.ecore)
+        api(libs.xtext.core)
+        api(libs.xtext.xbase)
+        api(project(":refinery-language-model"))
+        testFixturesApi(libs.xtext.testing)
+        mwe2(libs.xtext.generator)
+        mwe2(libs.xtext.generator.antlr)
+}
+
+sourceSets {
+        testFixtures {
+                java.srcDir("src/testFixtures/xtext-gen")
+                resources.srcDir("src/testFixtures/xtext-gen")
+        }
+}
+
+tasks.jar {
+        from(sourceSets.main.map { it.allSource }) {
+                include("**/*.xtext")
+        }
+}
+
+val generateXtextLanguage by tasks.registering(JavaExec::class) {
+        mainClass.set("org.eclipse.emf.mwe2.launch.runtime.Mwe2Launcher")
+        classpath(configurations.mwe2)
+        inputs.file("src/main/java/tools/refinery/language/GenerateProblem.mwe2")
+        inputs.file("src/main/java/tools/refinery/language/Problem.xtext")
+        outputs.dir("src/main/xtext-gen")
+        outputs.dir("src/testFixtures/xtext-gen")
+        outputs.dir("../language-ide/src/main/xtext-gen")
+        outputs.dir("../language-web/src/main/xtext-gen")
+        args("src/main/java/tools/refinery/language/GenerateProblem.mwe2", "-p", "rootPath=/$projectDir/..")
+}
+
+for (taskName in listOf("compileJava", "processResources", "processTestFixturesResources",
+                "generateEclipseSourceFolders")) {
+        tasks.named(taskName) {
+                dependsOn(generateXtextLanguage)
+        }
+}
+
+tasks.clean {
+        delete("src/main/xtext-gen")
+        delete("src/testFixtures/xtext-gen")
+        delete("../language-ide/src/main/xtext-gen")
+        delete("../language-web/src/main/xtext-gen")
+}
+
+sonarqube.properties {
+        SonarPropertiesUtils.addToList(properties, "sonar.exclusions", "src/textFixtures/xtext-gen/**")
+}
+
+eclipse.project.natures.plusAssign("org.eclipse.xtext.ui.shared.xtextNature")