build: convert Gradle scripts to Kotlin

Improves IDE support build scripts in IntelliJ.

There is no Eclipse IDE support, but Eclipse didn't have support for Groovy
either, so there is no degradation of functionality.

2 files changed, 127 insertions, 131 deletions

diff --git a/subprojects/frontend/build.gradle b/subprojects/frontend/build.gradle
deleted file mode 100644
index 4cc2c5d7..00000000
--- a/subprojects/frontend/build.gradle
+++ /dev/null
@@ -1,131 +0,0 @@
-plugins {
-        id 'refinery-frontend-workspace'
-        id 'refinery-sonarqube'
-}
-
-import org.siouan.frontendgradleplugin.infrastructure.gradle.RunYarn
-
-def viteOutputDir = "${buildDir}/vite"
-def productionResources = file("${viteOutputDir}/production")
-
-frontend {
-        assembleScript = 'run build'
-}
-
-configurations {
-        productionAssets {
-                canBeConsumed = true
-                canBeResolved = false
-        }
-}
-
-def installFrontend = tasks.named('installFrontend')
-
-def sourcesWithoutTypegen = fileTree('src') {
-        exclude '**/*.typegen.ts'
-}
-
-def assembleFrontend = tasks.named('assembleFrontend')
-assembleFrontend.configure {
-        dependsOn generateXStateTypes
-        inputs.dir 'public'
-        inputs.files sourcesWithoutTypegen
-        inputs.file 'index.html'
-        inputs.files('package.json', 'tsconfig.json', 'tsconfig.base.json', 'vite.config.ts')
-        inputs.file rootProject.file('yarn.lock')
-        outputs.dir productionResources
-}
-
-artifacts {
-        productionAssets(productionResources) {
-                builtBy assembleFrontend
-        }
-}
-
-def generateXStateTypes = tasks.register('generateXStateTypes', RunYarn) {
-        dependsOn installFrontend
-        inputs.files sourcesWithoutTypegen
-        inputs.file 'package.json'
-        inputs.file rootProject.file('yarn.lock')
-        outputs.dir 'src'
-        script = 'run typegen'
-        description = 'Generate TypeScript typings for XState state machines.'
-}
-
-def typecheckFrontend = tasks.register('typecheckFrontend', RunYarn) {
-        dependsOn installFrontend
-        dependsOn generateXStateTypes
-        inputs.dir 'src'
-        inputs.dir 'types'
-        inputs.files('package.json', 'tsconfig.json', 'tsconfig.base.json', 'tsconfig.node.json')
-        inputs.file rootProject.file('yarn.lock')
-        outputs.dir "${buildDir}/typescript"
-        script = 'run typecheck'
-        group = 'verification'
-        description = 'Check for TypeScript type errors.'
-}
-
-def lintFrontend = tasks.register('lintFrontend', RunYarn) {
-        dependsOn installFrontend
-        dependsOn generateXStateTypes
-        dependsOn typecheckFrontend
-        inputs.dir 'src'
-        inputs.dir 'types'
-        inputs.files('.eslintrc.cjs', 'prettier.config.cjs')
-        inputs.files('package.json', 'tsconfig.json', 'tsconfig.base.json', 'tsconfig.node.json')
-        inputs.file rootProject.file('yarn.lock')
-        if (project.hasProperty('ci')) {
-                outputs.file "${buildDir}/eslint.json"
-                script = 'run lint:ci'
-        } else {
-                script = 'run lint'
-        }
-        group = 'verification'
-        description = 'Check for TypeScript lint errors and warnings.'
-}
-
-def prettier = tasks.register('fixFrontend', RunYarn) {
-        dependsOn installFrontend
-        dependsOn generateXStateTypes
-        dependsOn typecheckFrontend
-        inputs.dir 'src'
-        inputs.dir 'types'
-        inputs.files('.eslintrc.cjs', 'prettier.config.cjs')
-        inputs.files('package.json', 'tsconfig.json', 'tsconfig.base.json', 'tsconfig.node.json')
-        inputs.file rootProject.file('yarn.lock')
-        script = 'run lint:fix'
-        group = 'verification'
-        description = 'Fix TypeScript lint errors and warnings.'
-}
-
-tasks.named('check') {
-        dependsOn(typecheckFrontend)
-        dependsOn(lintFrontend)
-}
-
-tasks.register('serveFrontend', RunYarn) {
-        dependsOn installFrontend
-        dependsOn generateXStateTypes
-        inputs.dir 'public'
-        inputs.files sourcesWithoutTypegen
-        inputs.file 'index.html'
-        inputs.files('package.json', 'tsconfig.json', 'tsconfig.base.json', 'vite.config.ts')
-        inputs.file rootProject.file('yarn.lock')
-        outputs.dir "${viteOutputDir}/development"
-        script = 'run serve'
-        group = 'run'
-        description = 'Start a Vite dev server with hot module replacement.'
-}
-
-tasks.named('clean') {
-        delete 'dev-dist'
-        delete fileTree('src') {
-                include '**/*.typegen.ts'
-        }
-}
-
-sonarqube.properties {
-        properties['sonar.sources'] = 'src'
-        property 'sonar.nodejs.executable', "${frontend.nodeInstallDirectory.get()}/bin/node"
-        property 'sonar.eslint.reportPaths', "${buildDir}/eslint.json"
-}
diff --git a/subprojects/frontend/build.gradle.kts b/subprojects/frontend/build.gradle.kts
new file mode 100644
index 00000000..4a51c74e
--- /dev/null
+++ b/subprojects/frontend/build.gradle.kts
@@ -0,0 +1,127 @@
+import org.siouan.frontendgradleplugin.infrastructure.gradle.RunYarn
+import tools.refinery.buildsrc.SonarPropertiesUtils
+
+plugins {
+        id("refinery-frontend-workspace")
+        id("refinery-sonarqube")
+}
+
+val viteOutputDir = "$buildDir/vite"
+val productionResources = file("$viteOutputDir/production")
+
+frontend {
+        assembleScript.set("run build")
+}
+
+val productionAssets: Configuration by configurations.creating {
+        isCanBeConsumed = true
+        isCanBeResolved = false
+}
+
+val sourcesWithoutTypeGen = fileTree("src") {
+        exclude("**/*.typegen.ts")
+}
+
+val generateXStateTypes by tasks.registering(RunYarn::class) {
+        dependsOn(tasks.installFrontend)
+        inputs.files(sourcesWithoutTypeGen)
+        inputs.file("package.json")
+        inputs.file(rootProject.file("yarn.lock"))
+        outputs.dir("src")
+        script.set("run typegen")
+        description = "Generate TypeScript typings for XState state machines."
+}
+
+tasks.assembleFrontend {
+        dependsOn(generateXStateTypes)
+        inputs.dir("public")
+        inputs.files(sourcesWithoutTypeGen)
+        inputs.file("index.html")
+        inputs.files("package.json", "tsconfig.json", "tsconfig.base.json", "vite.config.ts")
+        inputs.file(rootProject.file("yarn.lock"))
+        outputs.dir(productionResources)
+}
+
+artifacts {
+        add("productionAssets", productionResources) {
+                builtBy(tasks.assembleFrontend)
+        }
+}
+
+val typeCheckFrontend by tasks.registering(RunYarn::class) {
+        dependsOn(tasks.installFrontend)
+        dependsOn(generateXStateTypes)
+        inputs.dir("src")
+        inputs.dir("types")
+        inputs.files("package.json", "tsconfig.json", "tsconfig.base.json", "tsconfig.node.json")
+        inputs.file(rootProject.file("yarn.lock"))
+        outputs.dir("$buildDir/typescript")
+        script.set("run typecheck")
+        group = "verification"
+        description = "Check for TypeScript type errors."
+}
+
+val lintFrontend by tasks.registering(RunYarn::class) {
+        dependsOn(tasks.installFrontend)
+        dependsOn(generateXStateTypes)
+        dependsOn(typeCheckFrontend)
+        inputs.dir("src")
+        inputs.dir("types")
+        inputs.files(".eslintrc.cjs", "prettier.config.cjs")
+        inputs.files("package.json", "tsconfig.json", "tsconfig.base.json", "tsconfig.node.json")
+        inputs.file(rootProject.file("yarn.lock"))
+        if (project.hasProperty("ci")) {
+                outputs.file("$buildDir/eslint.json")
+                script.set("run lint:ci")
+        } else {
+                script.set("run lint")
+        }
+        group = "verification"
+        description = "Check for TypeScript lint errors and warnings."
+}
+
+val fixFrontend by tasks.registering(RunYarn::class) {
+        dependsOn(tasks.installFrontend)
+        dependsOn(generateXStateTypes)
+        dependsOn(typeCheckFrontend)
+        inputs.dir("src")
+        inputs.dir("types")
+        inputs.files(".eslintrc.cjs", "prettier.config.cjs")
+        inputs.files("package.json", "tsconfig.json", "tsconfig.base.json", "tsconfig.node.json")
+        inputs.file(rootProject.file("yarn.lock"))
+        script.set("run lint:fix")
+        group = "verification"
+        description = "Fix TypeScript lint errors and warnings."
+}
+
+tasks.check {
+        dependsOn(typeCheckFrontend)
+        dependsOn(lintFrontend)
+}
+
+tasks.register("serveFrontend", RunYarn::class) {
+        dependsOn(tasks.installFrontend)
+        dependsOn(generateXStateTypes)
+        inputs.dir("public")
+        inputs.files(sourcesWithoutTypeGen)
+        inputs.file("index.html")
+        inputs.files("package.json", "tsconfig.json", "tsconfig.base.json", "vite.config.ts")
+        inputs.file(rootProject.file("yarn.lock"))
+        outputs.dir("$viteOutputDir/development")
+        script.set("run serve")
+        group = "run"
+        description = "Start a Vite dev server with hot module replacement."
+}
+
+tasks.clean {
+        delete("dev-dist")
+        delete(fileTree("src") {
+                include("**/*.typegen.ts")
+        })
+}
+
+sonarqube.properties {
+        SonarPropertiesUtils.addToList(properties, "sonar.sources", "src")
+        property("sonar.nodejs.executable", "${frontend.nodeInstallDirectory.get()}/bin/node")
+        property("sonar.eslint.reportPaths", "$buildDir/eslint.json")
+}