blob: 102dc57e346b7deb9545de1f1533faaeca8ddd6a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
package hu.bme.mit.inf.dslreasoner.faulttree.transformation.cft2ft
import com.google.common.collect.ImmutableSet
import hu.bme.mit.inf.dslreasoner.faulttree.model.ft.ConstantEvent
import hu.bme.mit.inf.dslreasoner.faulttree.model.ft.Event
import hu.bme.mit.inf.dslreasoner.faulttree.model.ft.RandomEvent
import java.util.Set
import org.eclipse.xtend.lib.annotations.Data
@Data
class EventCollection {
val int falseEventCount
val int trueEventCount
val Set<RandomEvent> randomEvents
def containsFalseEvent() {
falseEventCount >= 1
}
def containsTrueEvent() {
trueEventCount >= 1
}
def getVariableEventCount() {
randomEvents.size
}
def containsRandomEvent() {
variableEventCount >= 1
}
def getCount() {
falseEventCount + trueEventCount + variableEventCount
}
def isEmpty() {
!containsFalseEvent && !containsTrueEvent && !containsRandomEvent
}
def containsExactlyOneRandomEvent() {
!containsFalseEvent && !containsTrueEvent && variableEventCount == 1
}
def toSingleRandomEvent() {
if (!containsExactlyOneRandomEvent) {
throw new IllegalStateException("Input collection is not a single random event")
}
randomEvents.head
}
static def builder() {
new Builder()
}
static class Builder {
var falseEventCount = 0
var trueEventCount = 0
val randomEventsBuilder = ImmutableSet.<RandomEvent>builder
private new() {
}
def add(Event event) {
switch (event) {
ConstantEvent:
if (event.failed) {
trueEventCount++
} else {
falseEventCount++
}
RandomEvent:
randomEventsBuilder.add(event)
default:
throw new IllegalArgumentException("Unknown event: " + event)
}
this
}
def addAll(EventCollection materializedEvens) {
falseEventCount += materializedEvens.falseEventCount
trueEventCount += materializedEvens.trueEventCount
randomEventsBuilder.addAll(materializedEvens.randomEvents)
this
}
def build() {
new EventCollection(falseEventCount, trueEventCount, randomEventsBuilder.build)
}
}
}
|