Trying to simplify Satellite case study

7 files changed, 292 insertions, 0 deletions

diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/CostObjective.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/CostObjective.xtend
new file mode 100644
index 00000000..3a8688e9
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/CostObjective.xtend
@@ -0,0 +1,13 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import hu.bme.mit.inf.dslreasoner.domains.satellite.queries.CostMetric
+
+class CostObjective extends MetricBasedGuidanceFunction {
+        new() {
+                super(CostMetric.instance)
+        }
+
+        override getName() {
+                "Cost"
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/ExcludedOptimisationInterpreter.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/ExcludedOptimisationInterpreter.xtend
new file mode 100644
index 00000000..ddf5748e
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/ExcludedOptimisationInterpreter.xtend
@@ -0,0 +1,85 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import java.util.Properties
+import org.moeaframework.Executor
+import org.moeaframework.Instrumenter
+import org.moeaframework.algorithm.PeriodicAction
+import org.moeaframework.core.TerminationCondition
+import org.moeaframework.core.spi.AlgorithmFactory
+import uk.ac.kcl.inf.mdeoptimiser.interfaces.cli.Run
+import uk.ac.kcl.inf.mdeoptimiser.languages.mopt.Optimisation
+import uk.ac.kcl.inf.mdeoptimiser.languages.mopt.SolverSpec
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.OptimisationInterpreter
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.executor.SolutionGenerator
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.moea.MoeaOptimisation
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.moea.algorithms.MoeaOptimisationAlgorithmProvider
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.moea.instrumentation.PopulationCollector
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.moea.problem.MoeaOptimisationProblem
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.operators.adaptation.MutationStepSizeStrategyFactory
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.output.MDEOBatch
+
+class ExcludedMoeaOptimisation extends MoeaOptimisation {
+        SolutionGenerator solutionGenerator
+        Instrumenter algorithmStepSizeInstrumenter
+
+        override execute(SolverSpec solverSpec, SolutionGenerator solutionGenerator) {
+                this.solutionGenerator = solutionGenerator
+                super.execute(solverSpec, solutionGenerator)
+        }
+
+        override Instrumenter runOptimisation(SolverSpec solverSpec, Properties optimisationProperties) {
+                val algorithmFactory = new AlgorithmFactory
+                algorithmFactory.addProvider(new MoeaOptimisationAlgorithmProvider)
+
+                algorithmStepSizeInstrumenter = new Instrumenter().addExcludedPackage("org.eclipse").withProblemClass(
+                        MoeaOptimisationProblem, solutionGenerator).attachApproximationSetCollector().attachElapsedTimeCollector().
+                        attachPopulationSizeCollector.attach(new PopulationCollector()).withFrequency(1).withFrequencyType(
+                                PeriodicAction.FrequencyType.STEPS)
+
+                var stepSizeStrategy = new MutationStepSizeStrategyFactory(solverSpec.algorithm, algorithmStepSizeInstrumenter).
+                        strategy
+
+                solutionGenerator.setMutationStepSizeStrategy(stepSizeStrategy)
+
+                // TODO: Place this in a better location. 
+                // Exclude JDK packages from Instrumenter
+                this.algorithmStepSizeInstrumenter.addExcludedPackage("jdk")
+
+                new Executor().usingAlgorithmFactory(algorithmFactory).withAlgorithm(solverSpec.algorithm.name) // Initialize problem with our solution generator
+                .withProblemClass(MoeaOptimisationProblem, solutionGenerator).withProperties(optimisationProperties).
+                        withInstrumenter(algorithmStepSizeInstrumenter).withTerminationCondition(
+                                optimisationProperties.get("terminationCondition") as TerminationCondition).run()
+
+                return algorithmStepSizeInstrumenter
+        }
+}
+
+class ExcludedOptimisationInterpreter extends OptimisationInterpreter {
+        val Optimisation model
+
+        new(String projectPath, Optimisation model) {
+                super(projectPath, model)
+                this.model = model
+        }
+
+        override start() {
+                // This model provider loads the model given by the user in the DSL
+                var solutionGenerator = new SolutionGenerator(model, getBreedingOperators, getMutationOperators,
+                        getModelProvider, getMetamodel);
+
+                return new ExcludedMoeaOptimisation().execute(model.solver, solutionGenerator)
+        }
+
+}
+
+class ExcludedRun extends Run {
+        override runBatch(String moptProjectPath, Optimisation optimisationModel, Integer batch, boolean singleBatch) {
+                val optimisationInterpreter = new ExcludedOptimisationInterpreter(moptProjectPath, optimisationModel);
+                val startTime = System.nanoTime();
+                val optimisationOutcome = optimisationInterpreter.start();
+                val endTime = System.nanoTime();
+                val experimentDuration = ((endTime - startTime) / 1000000);
+                val generatedRules = optimisationInterpreter.getRulegenOperators();
+                return new MDEOBatch(batch, experimentDuration, optimisationOutcome, generatedRules, singleBatch);
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/LocalSearchEngineManager.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/LocalSearchEngineManager.xtend
new file mode 100644
index 00000000..ee7f0060
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/LocalSearchEngineManager.xtend
@@ -0,0 +1,31 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import hu.bme.mit.inf.dslreasoner.domains.satellite.queries.SatelliteQueries
+import java.util.WeakHashMap
+import org.eclipse.emf.ecore.EObject
+import org.eclipse.viatra.query.runtime.api.AdvancedViatraQueryEngine
+import org.eclipse.viatra.query.runtime.api.ViatraQueryEngine
+import org.eclipse.viatra.query.runtime.api.ViatraQueryEngineOptions
+import org.eclipse.viatra.query.runtime.emf.EMFScope
+import org.eclipse.viatra.query.runtime.localsearch.matcher.integration.LocalSearchHints
+
+class LocalSearchEngineManager {
+        public static val INSTANCE = new LocalSearchEngineManager
+
+        val WeakHashMap<EObject, ViatraQueryEngine> engineMap = new WeakHashMap
+
+        private new() {
+        }
+
+        def getEngine(EObject eObject) {
+                engineMap.computeIfAbsent(eObject) [
+                        val scope = new EMFScope(it)
+                        val localSearchHints = LocalSearchHints.^default.build
+                        val options = ViatraQueryEngineOptions.defineOptions.withDefaultHint(localSearchHints).withDefaultBackend(
+                                localSearchHints.queryBackendFactory).build
+                        val engine = AdvancedViatraQueryEngine.on(scope, options)
+                        SatelliteQueries.instance.prepare(engine)
+                        engine
+                ]
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/MetricBasedGuidanceFunction.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/MetricBasedGuidanceFunction.xtend
new file mode 100644
index 00000000..1529794f
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/MetricBasedGuidanceFunction.xtend
@@ -0,0 +1,47 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import org.eclipse.viatra.query.runtime.api.IPatternMatch
+import org.eclipse.viatra.query.runtime.api.IQuerySpecification
+import org.eclipse.viatra.query.runtime.api.ViatraQueryMatcher
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.IGuidanceFunction
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.interpreter.guidance.Solution
+
+abstract class MetricBasedGuidanceFunction implements IGuidanceFunction {
+        val IQuerySpecification<? extends ViatraQueryMatcher<? extends IPatternMatch>> querySpecification
+
+        protected new(IQuerySpecification<? extends ViatraQueryMatcher<? extends IPatternMatch>> querySpecification) {
+                this.querySpecification = querySpecification
+                if (querySpecification.parameters.size != 1) {
+                        throw new IllegalArgumentException("Metric must have a single parameter")
+                }
+        }
+
+        override computeFitness(Solution model) {
+                val value = getMetricValue(model)
+                computeFitness(value)
+        }
+
+        protected def double computeFitness(double metricValue) {
+                metricValue
+        }
+
+        private def getMetricValue(Solution solution) {
+                val model = solution.model
+                val queryEngine = LocalSearchEngineManager.INSTANCE.getEngine(model)
+                val matcher = querySpecification.getMatcher(queryEngine)
+                val iterator = matcher.allMatches.iterator
+                if (!iterator.hasNext) {
+                        throw new IllegalStateException("Too few matches")
+                }
+                val objectValue = iterator.next.get(0)
+                if (objectValue instanceof Number) {
+                        val doubleValue = objectValue.doubleValue
+                        if (iterator.hasNext) {
+                                throw new IllegalStateException("Too many matches")
+                        }
+                        doubleValue
+                } else {
+                        throw new IllegalStateException("Metric value must be a number")
+                }
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/PatternMatchConstraint.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/PatternMatchConstraint.xtend
new file mode 100644
index 00000000..b238e64f
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/PatternMatchConstraint.xtend
@@ -0,0 +1,29 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import com.google.common.collect.ImmutableList
+import hu.bme.mit.inf.dslreasoner.domains.satellite.queries.SatelliteQueries
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.IGuidanceFunction
+import uk.ac.kcl.inf.mdeoptimiser.libraries.core.optimisation.interpreter.guidance.Solution
+
+class PatternMatchConstraint implements IGuidanceFunction {
+        static val CONSTRAINT_ANNOTATION_NAME = "Constraint"
+
+        val queries = ImmutableList.copyOf(SatelliteQueries.instance.specifications.filter [
+                allAnnotations.exists[name == CONSTRAINT_ANNOTATION_NAME]
+        ])
+
+        override getName() {
+                "PatternMatch"
+        }
+
+        override computeFitness(Solution solution) {
+                val model = solution.model
+                val queryEngine = LocalSearchEngineManager.INSTANCE.getEngine(model)
+                var int matchCount = 0
+                for (query : queries) {
+                        val matcher = query.getMatcher(queryEngine)
+                        matchCount += matcher.countMatches
+                }
+                matchCount
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/SatelliteMdeOptimiserMain.xtend b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/SatelliteMdeOptimiserMain.xtend
new file mode 100644
index 00000000..c5a30f94
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/SatelliteMdeOptimiserMain.xtend
@@ -0,0 +1,52 @@
+package hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo
+
+import java.io.BufferedReader
+import java.io.BufferedWriter
+import java.io.FileReader
+import java.io.FileWriter
+import java.util.Map
+import org.eclipse.emf.ecore.EPackage
+import org.eclipse.emf.ecore.resource.Resource
+import org.eclipse.emf.ecore.xmi.impl.XMIResourceFactoryImpl
+import satellite.SatellitePackage
+import uk.ac.kcl.inf.mdeoptimiser.languages.MoptStandaloneSetup
+
+class SatelliteMdeOptimiserMain {
+        static val PROJECT_PATH = "."
+        static val MOPT_PATH = "src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/satellite.mopt"
+
+        private new() {
+                new IllegalStateException("This is a static utility class and should not be instantiated directly.")
+        }
+
+        public static def void main(String[] args) {
+                Resource.Factory.Registry.INSTANCE.extensionToFactoryMap.put(Resource.Factory.Registry.DEFAULT_EXTENSION,
+                        new XMIResourceFactoryImpl)
+                EPackage.Registry.INSTANCE.put(SatellitePackage.eNS_URI, SatellitePackage.eINSTANCE)
+                fixupHenshinModel("model/satellite.henshin", "model/satellite_fixup.henshin",
+                        #{"satellite.ecore" -> SatellitePackage.eNS_URI})
+                val injector = new MoptStandaloneSetup().createInjectorAndDoEMFRegistration();
+                injector.getInstance(ExcludedRun).run(PROJECT_PATH, MOPT_PATH)
+        }
+
+        private def static void fixupHenshinModel(String originalPath, String outputPath, Map<String, String> remapMap) {
+                val reader = new BufferedReader(new FileReader(originalPath))
+                try {
+                        val writer = new BufferedWriter(new FileWriter(outputPath))
+                        try {
+                                var String line
+                                while ((line = reader.readLine) !== null) {
+                                        for (entry : remapMap.entrySet) {
+                                                line = line.replace(entry.key, entry.value)
+                                        }
+                                        writer.write(line)
+                                        writer.write("\n")
+                                }
+                        } finally {
+                                writer.close
+                        }
+                } finally {
+                        reader.close
+                }
+        }
+}
diff --git a/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/satellite.mopt b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/satellite.mopt
new file mode 100644
index 00000000..138ea309
--- /dev/null
+++ b/Domains/hu.bme.mit.inf.dslreasoner.domains.satellite/src/hu/bme/mit/inf/dslreasoner/domains/satellite/mdeo/satellite.mopt
@@ -0,0 +1,35 @@
+problem {
+        basepath <model>
+        metamodel <satellite.SatellitePackage>
+        model <../inputs/SatelliteInstance.xmi>
+}
+
+goal {
+        objective Cost minimise java { "hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo.CostObjective" }
+        constraint PatternMatch java { "hu.bme.mit.inf.dslreasoner.domains.satellite.mdeo.PatternMatchConstraint" }
+}
+
+search {
+        mutate using <satellite_fixup.henshin> unit "addCubeSat3U"
+//      mutate { "CubeSat3U" }
+//      mutate { "CubeSat6U" }
+//      mutate { "SmallSat" }
+//      mutate { "InterferometryPayload" }
+//      mutate { "CommSubsystem" }
+//      mutate { "DirectedCommunicationLink" }
+}
+
+solver {
+        optimisation provider moea algorithm NSGAII {
+                variation: mutation
+                population: 25
+                mutation.step: 3
+                mutation.strategy: random
+        }
+
+        termination {
+                time: 120
+        }
+
+        batches 1
+}
\ No newline at end of file